- NAME
- SYNOPSIS
- METHODS
- LOADING DRIVERS
- WRITING DRIVERS
  - METHODS SUBCLASSES MUST IMPLEMENT
  - METHODS SUBCLASSES MAY IMPLEMENT OR OVERRIDE
- SOURCE
- MAINTAINERS
- AUTHORS
- COPYRIGHT

# NAME

Test2::IPC::Driver - Base class for Test2 IPC drivers.

# SYNOPSIS

        package Test2::IPC::Driver::MyDriver;

        use base 'Test2::IPC::Driver';

        ...

# METHODS

$self->abort($msg)

  If an IPC encounters a fatal error it should use this. This will print the message to STDERR with `'IPC Fatal Error: '` prefixed to it, then it will forcefully exit 255. IPC errors may occur in threads or processes other than the main one, this method provides the best chance of the harness noticing the error.

$self->abort_trace($msg)

  This is the same as `$ipc->abort($msg)` except that it uses `Carp::longmess` to add a stack trace to the message.

$false = $self->use_shm

  The base class always returns false for this method. You may override it if you wish to use the SHM made available in Test2::API/Test2::API::Instance.

# LOADING DRIVERS

Test2::IPC::Driver has an `import()` method. All drivers inherit this import method. This import method registers the driver.

In most cases you just need to load the desired IPC driver to make it work. You should load this driver as early as possible. A warning will be issued if you load it too late for it to be effective.

        use Test2::IPC::Driver::MyDriver;
        ...

# WRITING DRIVERS

        package Test2::IPC::Driver::MyDriver;
        use strict;
        use warnings;

        use base 'Test2::IPC::Driver';

        sub is_viable {
            return 0 if $^O eq 'win32'; # Will not work on windows.
            return 1;
        }

        sub add_hub {
            my $self = shift;
            my ($hid) = @_;

            ... # Make it possible to contact the hub
        }

        sub drop_hub {
            my $self = shift;
            my ($hid) = @_;

            ... # Nothing should try to reach the hub anymore.
        }

        sub send {
            my $self = shift;
            my ($hid, $e, $global) = @_;

            ... # Send the event to the proper hub.

            # If you are using the SHM you should notify other procs/threads that
            # there is a pending event.
            Test2::API::test2_ipc_set_pending($uniq_val);
        }

        sub cull {
            my $self = shift;
            my ($hid) = @_;

            my @events = ...; # Here is where you get the events for the hub

            return @events;
        }

        sub waiting {
            my $self = shift;

            ... # Notify all listening procs and threads that the main
            ... # process/thread is waiting for them to finish.
        }

        1;

## METHODS SUBCLASSES MUST IMPLEMENT

$ipc->is_viable

  This should return true if the driver works in the current environment. This should return false if it does not. This is a CLASS method.

$ipc->add_hub($hid)

  This is used to alert the driver that a new hub is expecting events. The driver should keep track of the process and thread ids, the hub should only be dropped by the proc+thread that started it.

          sub add_hub {
              my $self = shift;
              my ($hid) = @_;

              ... # Make it possible to contact the hub
          }

$ipc->drop_hub($hid)

  This is used to alert the driver that a hub is no longer accepting events. The driver should keep track of the process and thread ids, the hub should only be dropped by the proc+thread that started it (This is the drivers responsibility to enforce).

          sub drop_hub {
              my $self = shift;
              my ($hid) = @_;

              ... # Nothing should try to reach the hub anymore.
          }

$ipc->send($hid, $event);
$ipc->send($hid, $event, $global);

  Used to send events from the current process/thread to the specified hub in its process+thread.

          sub send {
              my $self = shift;
              my ($hid, $e) = @_;

              ... # Send the event to the proper hub.

              # If you are using the SHM you should notify other procs/threads that
              # there is a pending event.
              Test2::API::test2_ipc_set_pending($uniq_val);
          }

  If `$global` is true then the driver should send the event to all hubs in all processes and threads.

@events = $ipc->cull($hid)

  Used to collect events that have been sent to the specified hub.

          sub cull {
              my $self = shift;
              my ($hid) = @_;

              my @events = ...; # Here is where you get the events for the hub

              return @events;
          }

$ipc->waiting()

  This is called in the parent process when it is complete and waiting for all child processes and threads to complete.

          sub waiting {
              my $self = shift;

              ... # Notify all listening procs and threads that the main
              ... # process/thread is waiting for them to finish.
          }

## METHODS SUBCLASSES MAY IMPLEMENT OR OVERRIDE

$bool = $ipc->use_shm()

  True if you want to make use of the Test2::API/Test2::API::Instance SHM.

$bites = $ipc->shm_size()

  Use this to customize the size of the SHM space. There are no guarantees about what the size will be if you do not implement this.

# SOURCE

The source code repository for Test2 can be found at http://github.com/Test-More/test-more/.

# MAINTAINERS

Chad Granum <exodist@cpan.org>

# AUTHORS

Chad Granum <exodist@cpan.org>

# COPYRIGHT

Copyright 2016 Chad Granum <exodist@cpan.org>.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

See http://dev.perl.org/licenses/